START > APPLESCRIPT > Erklärende Scripts > Netzwerk-Laufwerke / Volumes mounten

Netzwerk-Laufwerke / Volumes mounten

Sind alle für den Mount des Volumes nötigen Angaben im Script gemacht (Username, Passwort) findet der Mount vollautomatisch ohne Abfrage von Benutzername und Passwort statt, da diese vom Script übergeben werden. Man kann aber auch Teile (z.B. das Passwort) im Script weglassen. Dann werden diese bei Ausführung des Scripts automatisch vom System per Dialog abgefragt, bzw. (wenn hinterlegt) auf die Informationen aus dem Schlüsselbund zurückgegriffen.

Da der mount volume-Befehl zu den StandardAdditions gehört, muss er sich nicht zwangsläufig in einem Finder-Block befinden, auch wenn man dies vielleicht vermuten würde.

-- ==================================================
-- mount von Macs per AFP (Apple Filing Protokoll)
-- ==================================================

(* Die Langform *)
mount volume "afp://IP_or_servername/volume" as user name ¬
"username" with password "passwort"

(* Die Kurzform *)
mount volume "afp://username:passwort@ip_or_servername/volume"

-- ==================================================
-- mount von PCs per SMB (Server Message Block, Samba)
-- ==================================================

(* Die Kurzform *)
mount volume "smb://domain;username:passwort@IP_or_servername/volume/"

 Im Scripteditor öffnen
Problem afp-Mount mit «leerem Passwort»

HINWEIS: Probleme machen in diesem Zusammenhang afp-Volumes, für die kein Passwort vergeben wurde. Diese lassen sich mit dieser Methode zwar mounten, doch leider wird trotzdem immer nach dem Passwort gefragt. Dies lässt sich leider nicht umgehen. Es sollte also immer ein Passwort vergeben sein, wenn diese Methode Anwendung finden soll. (Und sonst natürlich auch). Bei smb-Volumes hingegen kann man irgendein Passwort übergeben, wenn keines definiert ist. Dann wird klaglos ohne Abfrage gemounted.

Mehrere afp-Volumes eines Servers per AppleScript mounten

Leider funktioniert es unter Mac OS X nicht mehr zuverlässig, mehrere Volumes eines Servers über ein solches AppleScript-Konstrukt der Reihe nach zu mounten (es plagt einen die Fehlermeldung: "Disks: Some Objects wasn't found."). Ich bin schon fast daran verzweifelt. Unter Leopard soll das ganze aber «super zuverlässig» laufen, ich mag aber nicht so recht daran glauben. Bin mal gespannt.

(siehe auch Tipp unten im schwarzen Kasten)


LÖSUNG GEFUNDEN!!! Nun habe ich doch noch das Problem ausmachen können und eine zuverlässige Script-Lösung für den «Serien-Mount» von einem Server gefunden. Wer also genau diese beschriebenen Probleme hat, der möge bitte mal folgendes AppleScript ausprobieren und Feedback geben, ob's hiermit einwandfrei funktioniert. Bitte die beiden Variablen serv und volList entsprechend anpassen, und das Skript als "Programm" speichern! Passwort und Usernamen brauchen n i c h t als Klartext ins Script eingetragen werden, sondern werden beim ersten Start der Script-Application abgefragt und als Property gespeichert (bis zum nächsten Compilieren):

property usrn : "" --< do NOT pick in your username here!
property pswd : "" --< do NOT pick in your password here!

(* Just save this script as application. Within first script-start you will be askedfor username & password and it will be stored as property in the script-app for the future.But please customize the vars "serv" and "volList" in the next two paragraphs,that's all to do in Script Editor. *)

set serv to "192.0.0.0"
set volList to {"Voume1", "Volume2", "Volume3"}
set firstMount to true

-- ::::::::::::::::::::::::::::::::::::::::  hohabadu.de  ::::::::::::::::::::::::::::::::::::::::

(*   (c) by H =:o) L G I  (alias Holger Hansen)Ich würde mich freuen, wenn bei Verwendung des Codes oder Teilen davondiese Zeilen erhalten bleiben, zumindest aber die Zeile m. d. Hinweis auf die Website *)


-- username & password configuration
if usrn is "" and pswd is "" then
   set usrn to text returned of (display dialog "Username for Server \"" & serv & "\":" default answer "username")
   set pswd to text returned of (display dialog "Password for Server \"" & serv & "\":" default answer "password" with hidden answer)
end if


-- mounting volumes, if necessary and the Server is available

-- check, if the server is available
if my checkServer(serv) then
   repeat with vol in volList
      -- check, if volume isn't already mounted
      if vol is not in (list disks) then
         -- check, if that's the first attempt to mount a volume of the server
         if firstMount then
            try
               mount volume "afp://" & usrn & ":" & pswd & "@" & serv & "/" & vol
            on error
               mount volume "afp://" & serv & "/" & vol
            end try
         else
            mount volume "afp://" & serv & "/" & vol
         end if
      end if
      set firstMount to false
   end repeat
else
   activate
   display dialog "Server \"" & serv & "\" isn't available at this moment!" with icon stop giving up after 20
end if


on checkServer(ServerIP)
   try
      do shell script "ping -t2 -c1 " & ServerIP
      return true
   on error
      return false
   end try
end checkServer

 Im Scripteditor öffnen
Kommentar schreiben

Andreas |  02.12.2016, 08:36:41 |  kostka@gmx.net  77.179.64.254 = x4db340fe.dyn.telefonica.de
Hallo,Vielen Dank für das tolle script. Leider lässt sich der home-Ordner auf meiner Synology-Diskstation damit nicht Montan. Alle anderen Ordner funktionieren problemlos über afp. Was kann der Fehler sein??MacOS 10.12.2 Beta (16C53a)GrüßeAndreas 

Manuel |  22.09.2016, 17:45:56 |  217.233.135.224 = pD9E987E0.dip0.t-ipconnect.de
Hi,seit dem Upgrade auf Mac OS Sierra, wird beim mount Befehl immer ein Dialog mit User und Passwort geöffnet, den ich dann manuell mit verbinden bestätigen muss. Kann man das abstellen? Vorher hat es auch funktioniert.So sieht mein Script aus:mount volume "afp://User:Passwort@192.xxx.xxx.xx/Qmultimedia"mount volume "afp://User:Passwort@192.xxx.xxx.xx/Public"mount volume "afp://User:Passwort@192.xxx.xxx.xx/Multimedia"Danke 

Serge |  08.01.2016, 18:51:31 |  93.130.75.7 = x5d824b07.dyn.telefonica.de
Hey, vielen Dank für den Skript! Hab dadurch Zeit gesparrt :) 

H =:o) L G I |  14.07.2015, 23:18:16 |  93.214.199.149 = p5DD6C795.dip0.t-ipconnect.de
Hi, André. Hmm. Weiß ich jetzt nicht so direkt und kann leider auch nicht testen. Hast Du es schon mit single quotes versucht? Also um den Volume Name meine ich... Versuch wär's wert. Oder am Ende einfach "& quoted form of vol" statt "& vol". Viel Erfolg. H =:o) L G I 

André |  14.07.2015, 18:45:20 |  188.99.90.38 = dslb-188-099-090-038.188.099.pools.vodafone-ip.de
Hallo,schönes Script, kann auch alle LW verbinden wie geplant. Vielen Dank!Nur bei dem Laufwerk mit Leerzeichen geht es nicht. Habe es schon mit "\" versucht, geht leider nicht.Hast Du noch einen Tip dafür?Danke.André  

Johannes |  20.06.2015, 22:29:02 |  mail@johannes-lomnitz.de  87.79.72.121 = static-87-79-72-121.netcologne.de
Hallo,ich versuche folgendes Ziel zu erreichen:1. Mounten eines Ordners im lokalen Netzwerk 2. - sofern nicht im LAN - Mounten eines Netzwerkes über das Internet.Der Zugriff manuell (cmd + K) über afp://... funktioniert sowohl für (1) als auch für (2) einwandfrei.Bisher verwende ich folgendes Script:tell application "Finder" try mount volume "afp://192.168.x.x/Daten" mount volume "afp://xxx.synology.me/Daten" end tryend tellWenn ich das Script so von extern ausführe, hängt sich der Mac leider auf, da er offenbar dauerhaft versucht lokal zu Verbinden. Kann mir jemand die Zeilen umbauen, so dass nur eine gewisse Anzahl von Versuchen erfolgt? Einzeln funktionieren beide Zeilen tadellos. Danke für eure Hilfe vorab! 

H =:o) L G I |  17.05.2015, 16:50:47 |  91.57.203.241 = p5B39CBF1.dip0.t-ipconnect.de
Hi, Ma Lo. - Das ist eine wirklich gute Frage... Wenn ich Du wäre, würde ich das Passwort ändern ,-) - Falls Du eine andere Lösung findest, kann Du es uns hier ja wissen lassen...!? Gruß vom H =:o) L G I 

Ma Lo |  07.05.2015, 23:04:07 |  89.0.214.239 = xdsl-89-0-214-239.netcologne.de
Hey,das Skript beschreibt genau mein Problem.Was kann ich machen, wenn mein Passwort ein "@" Zeichen beinhaltet,leider kommt dann eine Fehlermeldung, dass das PW falsch sei.Muss ich etwas vorranstellen, dass das "Sonderzeichen @" entwertet?Dnake.MfG 

H =:o) L G I |  17.01.2015, 16:35:15 |  93.214.209.98 = p5DD6D162.dip0.t-ipconnect.de
Hi, Normski - Nein, hab weder eine wirkliche Idee noch Mavericks, so dass ich es ausprobieren könnte. Versuche mal den Teil des Scripts zu lokalisieren, der es nicht zulässt, dass Du es als App speichern kanns (einfach nur Teile kompilieren lassen). Das kannst Du am einfachsten machen, indem Du Teile mit (* und *) deaktivierst... 

Normksi |  17.01.2015, 13:47:39 |  comevoi@yahoo.de  84.72.69.130 = 84-72-69-130.dclient.hispeed.ch
Hallo Holger - sieht gut aus. Wollte ich ausprobieren, lässt sich aber nicht als Applikation Speicher.Ablage/Sichern/Dateiformat ProgrammBin unter Mavericks, ist da etwas anders?Any idea? 

H =:o) L G I |  06.03.2014, 21:54:44 |  91.57.210.158 = p5B39D29E.dip0.t-ipconnect.de
Hallo Manuel. Das liegt schlichtweg daran, dass zu dem Zeitpunkt noch gar keine Netzwerkverbindung besteht bzw. möglich ist, da noch nicht alle notwendigen Dienste hochgefahren sind. Wenn Du ein delay einbaust, sollte es funktionieren. Oder Du baust eine Überprüfung der Netzwerkverfügbarkeit ein. Musste mal ein wenig forschen und tüfteln, wie Du das bewerkstelligst. Scripten soll ja auch ein bisschen Sport bleiben... ,-) 

Manuel |  06.03.2014, 21:01:39 |  manuel.fr@icloud.com  84.145.156.159 = p54919C9F.dip0.t-ipconnect.de
habe die Datei im autostart drin allerdings kommt dann immer die Meldung "isn't available at this moment!" Starte ich es kurz darauf kommt keine Fehlermeldung, woran könnte das liegen?? 

Phil |  07.01.2014, 22:15:56 |  178.194.218.252 = 252.218.194.178.dynamic.wline.res.cust.swisscom.ch
Genial, vielen Dank für den Skript. Nun geht es noch ans Verstehen, wie dat Ding läuft. 

Sascha |  20.04.2013, 18:23:52 |  88.153.120.58 = ip-88-153-120-58.hsi04.unitymediagroup.de
Super geil!Funktioniert einwandfrei, endlich alle Shares (12 Stk.) meines nas4free auf einen Schlag verbinden.  

Patrick |  02.01.2013, 14:23:29 |  91.61.209.138 = p5B3DD18A.dip0.t-ipconnect.de
Der Beitrag war wirklich hilfreich.Allerdings hätte ich da noch eine Frage: Wenn man Username und Passwort auslässt, dann fragt Finder automatisch danach.Mir genügt es allerdings, wenn er sich als Gast anmeldet. Wie kann ich das im Skript mit angeben?Danke schonmal im Voraus! 

Lukas Schmid |  27.01.2012, 18:32:24 |  schmilu1@gmail.com  91.138.27.205 = 205-27-138-91.dyn.cable.fcom.ch
halloperfekte Vorgabe, danke das teil läuft einwandfrei gruss lukas 

Björn |  04.06.2011, 09:21:58 |  gemini186@gmx.de  88.70.166.226 = dslb-088-070-166-226.088.070.pools.vodafone-ip.de
Vielen Dank, läuft bei mir einwandfrei und wird nun täglich zum einfachen mounten von 4 Volumen genutzt. Gruß BjörnOS 10.6.7 

holle |  10.02.2011, 10:13:58 |  77.177.207.104 = x4db1cf68.dyn.telefonica.de
Danke !ich mußte aber das Script n bischen später starten, sonst bekom ich die fehlermeldung....darum hab ich am anfang "delay 5.5" eingefügt.Dann funktioniert es wunderbar unter 10.6.6.iMac 2,93 mit SSD 16 GB Ram. 

Sevvi |  23.01.2011, 10:36:46 |  efh@gmx.tm  188.22.135.146 = 188-22-135-146.adsl.highway.telekom.at
Hallo,ich finde diesen Script wirklich sehr hilfreich. Ich habe diesen auch so erweitert um auf mehrere verschiedene Geräte (also unterschiedliche IP`s) zugreifen zu können. Funktioniert reibungslos.Ich würde aber gern die Abfrage von Benutzername und Passwort etwas verbessern - wenn das möglich ist.Ich würde gern als erstes den Scrip meinen BN und PW mit dem ich am System angemeldet bin abfragen lassen, und nur dann zur Eingabe dieser Daten auffordern wenn BN und PW anders sind als die Anmeldung.Wenn ich also mit am System mit BN "heinrich" und PW "crypt" angemeldet bin und auch zum Beispiel die NAS im Netzwerk über den gleichen Benutzer verfügt, dann würde der Script ohne eine Abfrage durchlaufen und alle gewünschten Laufwerke verbinden. Ist jemand anders am System angemeldet und das Script wird ausgeführt kommt dann natürlich die Abfrage.Ist es denn möglich das so zu realisieren ?Danke schon mal und macht weiter so !! 

Nille |  22.08.2009, 14:42:18 |  91.32.81.81 = p5B205151.dip0.t-ipconnect.de
Vielen Dank fürs Script! Ich habe es um rsync Befehle erweitert und kann nun sehr zügig ein Backup auf mein NAS machen! 

Lars |  19.08.2008, 10:31:12 |  213.178.70.25 = 213.178.70.25
Hallo,erst einmal vielen Dank für das Script. Es funktioniert wunderbar unter 10.4 als auch unter 10.5. Ich habe es in der Seitenleiste und das mounten geht auch fix. Ich konnte es (als Apple Script Anfänger) recht einfach erweitern. So lassen sich nun alle meine Volumes auf verschiedenen Servern mit einem klick mounten. 

mundgerecht |  01.02.2008, 10:30:48 |  at gmail.com  83.64.114.230 = 83-64-114-230.static.upcbusiness.at
auch in der seitenleiste habe ich eine verzögerung, am schnellsten gehts, finde ich, also unmerkbar, wenn man die gemounteten festplatten am desktop anzeigen lässtdanke für das script  

H =:o) L G I |  31.01.2008, 18:25:28 |  89.53.72.231 = 89.53.72.231
habe auch erste erfahrungen machen können: du solltest die volumes unter devices in die seitenleiste ziehen. wenn sich die zugänge im schlüsselbund befinden, dann merkt man (soweit meine erfahrung) gar nicht, ob's nun gemounted war, oder nicht. hängt natürlich auch davon ab, auf was man zugreifen möchte. wenn's ein anderer rechner im ruhezustand ist, kann's natürlich mal einen tick dauern, ist's hingegen eine schnelle server-verbindung ist, spürt man den mount gar nicht. 

mundgerecht |  31.01.2008, 13:12:53 |  at gmail.com  83.64.114.230 = 83-64-114-230.static.upcbusiness.at
hallo, mounten unter leopard suckt, da die verbindung nicht aufrecht bleibt, sondern wenn man wieder darauf zugreifen will, sich der finder erst wieder neu connectet ... das neeervt irrsinnig, weiss wer abhilfe? ..gemountet is gemountet.. ka .. ausserdem nervt die neue finderleiste gewaltig..icch glaub ich installier mir wieder 10.4 

H =:o) L G I |  06.11.2007, 22:29:37 |  89.53.94.182 = 89.53.94.182
Hab ihr schon Erfahrungen mit dem Mount unter Leopard machen können? 



Powered By CMSimple Design By NMuD Top