(*     iCalEventRenamer v0.1 - hohabadu.de     *)

-- ::::::::::::::::::::::::::::::::::::::::  hohabadu.de  ::::::::::::::::::::::::::::::::::::::::

set AlterName to text returned of (display dialog "Zu suchenden Termin-Namen eingeben:" default answer "Alter Terminname")
set NeuerName to text returned of (display dialog "Zu ersetzenden Termin-Namen eingeben:" default answer "Neuer Terminname")
tell application "iCal" to set Kalenderliste to name of every calendar as list
set KalenderAuswahl to ¬
   choose from list ({">>>>> IN ALLEN KALENDERN <<<<<"} & Kalenderliste) with prompt ¬
      "Terminnamen in welchem Kalender ändern?." without multiple selections allowed
if KalenderAuswahl is {">>>>> IN ALLEN KALENDERN <<<<<"} then
   display dialog "Den Terminnamen
    \"" & AlterName & "\"
wirklich in allen Kalendern auf
    \"" & NeuerName & "\"
ändern?" with icon 2
   repeat with Kalendername in Kalenderliste
      my TerminAendern(Kalendername, AlterName, NeuerName)
   end repeat
   display alert "Termine wurden umbenannt."
else
   if KalenderAuswahl is not false then
      set Kalendername to item 1 of KalenderAuswahl
      my TerminAendern(Kalendername, AlterName, NeuerName)
      display alert "Termine wurden umbenannt."
   else
      display alert "Es wurde kein Kalender ausgewählt!"
   end if
end if

on TerminAendern(Kal, Alt, Neu)
   tell application "iCal"
      set dieTermine to every event of calendar Kal whose summary is Alt
      repeat with einTermin in dieTermine
         set summary of einTermin to Neu
      end repeat
   end tell
end TerminAendern

---

 Im Scripteditor öffnen